關於 Flash Preloader

大家好，我是奶綠茶
今天來講解一下關於 Flash Preloader 的概念
在製作 Flash WebSite 時, 為了避免一開始讓使用者等太久
所以都會製作一個 Loading 的畫面, 讓使用者知道目前的載入進度
有許多人問我，為何當畫面出現時, 己經載到百分之30以上
因為 Flash 至少要載入完畢第一個影格的資料, 才會出現畫面
曾看過設計師為了要讓 Loading 美美的, 放了一個 1mb 的影片動畫
結果當然是一片白, 什麼都看不到。
所以應該要避免
1.第一個影格上有太多的元件、圖片
2.Library 裡的元件，如果有選“匯出到第一個影格時“，也會增加第一影格的大小。
要決解這問題最好的方法就是
方法一：
把 Loading 製作成一個獨立的 swf 檔
用該檔去載入你的主 swf 檔

方法二：
或是可以使用 FlexSDK 裡的 [Frame(fractoryClass="預載用的類別名稱")] 表籤
今天就來解說這樣的製作方法
主程式 Main.as 和一般的寫法都一樣，只要在上方加入該 Tag

package {
 import flash.display.Bitmap;
 import flash.display.Sprite;
 import flash.events.Event;
 [Frame(factoryClass="Preloader")] // 指定預載用的類別為 Preloader
 public class Main extends Sprite {

  [Embed(source='buttle2007.jpg')] //放一張照片測試用
  public static const JPG:Class;

  public function Main():void {
   if (stage)
    init();
   else
    addEventListener(Event.ADDED_TO_STAGE, init);
  }
  private function init(e:Event = null):void {
   removeEventListener(Event.ADDED_TO_STAGE, init);
   // entry point
   addChild(new JPG() as Bitmap);
  }
 }
}

Preloader.as
用 EnterFrame 去偵測影格是否載入完畢
完成後，使用 getDefinitionByName("Main") 把 Main 類別找出並建構他。

package {
 import 略
 public class Preloader extends MovieClip { // 一定要 extends MovieClip
  private var m_tf:TextField; // 顯示用的文字
  public function Preloader(){
   if (stage){
    stage.scaleMode = StageScaleMode.NO_SCALE;
    stage.align = StageAlign.TOP_LEFT;
   }
   addEventListener(Event.ENTER_FRAME, checkFrame);
   loaderInfo.addEventListener(ProgressEvent.PROGRESS, progress);
   loaderInfo.addEventListener(IOErrorEvent.IO_ERROR, ioError);
   // show loader
   addChild(m_tf = new TextField);
   m_tf.x = stage.stageWidth >> 1;
   m_tf.y = stage.stageHeight >> 1;
  }
  private function ioError(e:IOErrorEvent):void {
   trace(e.text);
  }
  private function progress(e:ProgressEvent):void {
   // update loader
   m_tf.text = int(e.bytesLoaded / e.bytesTotal * 100) + "%";
  }
  private function checkFrame(e:Event):void {
   if (currentFrame == totalFrames) {    
    stop();
    loadingFinished();
    startup();
   }
  }
  private function loadingFinished():void {
   removeEventListener(Event.ENTER_FRAME, checkFrame);
   loaderInfo.removeEventListener(ProgressEvent.PROGRESS, progress);
   loaderInfo.removeEventListener(IOErrorEvent.IO_ERROR, ioError);
   
   // hide loader
   removeChild(m_tf);
   m_tf = null;  
  }

  private function startup():void {
   var mainClass:Class = getDefinitionByName("Main") as Class;
   if (parent == stage)
    stage.addChildAt(new mainClass() as DisplayObject, 0);
   else
    addChildAt(new mainClass() as DisplayObject, 0);
  }
 }
}

Compile時，要選的是 Main.as 檔喔
當這樣發怖後, 使用 decompile 軟體來看一下
會發現影格自動變成了二個影格, Preloader.as在第一影格