跳到主要內容

氣泡事件與客製化事件

AS3最好用的就是新的事件流
而且可以使用氣泡事件的方法, 一路往上打, 非常的好用
不要再寫像是AS2的 parent.parent.parent.gotoAndPlay(2)了

假設場景結構如下
Stage MainTimeline Loader(載入Child.swf)
當Child.swf裡的按鈕被按下時, 主時間要開始播放
可以用類似AS2的寫法是 MovieClip(parent.parent).gotoAndPlay(2);

AS3,可以叫Child.swf發送氣泡事件往上層打, 一路的可視可件都可以偵聽的到。
如果想要發事件時, 一起帶個參數出去
可以寫個 get 的屬性, 透過偵聽者函式 e.target即可得到發出事件者
或是可以發送一個客製化的事件, 就不需要寫 get 屬性。


Child.swf Child.as
該swf上有二個按鈕, 名稱為:btn_mc , btn2_mc
package  {
import flash.display.MovieClip;
import flash.display.Sprite;
import flash.events.Event;
import flash.events.MouseEvent;
import milkmidi.CustomEvent;
/**
* ...
* @author milkmidi
*/
public class Child extends Sprite {  

public var btn_mc :MovieClip;  
public var btn2_mc :MovieClip;  
private var _msg :String = "我是Child.swf的變數";
public function Child() {
btn_mc.buttonMode = true;
btn_mc.addEventListener(MouseEvent.CLICK , _btnClickHandler);

btn2_mc.buttonMode = true;
btn2_mc.addEventListener(MouseEvent.CLICK , _btn2ClickHandler);
}  
private function _btnClickHandler(e:MouseEvent):void {

//發送氣泡事件, 事件名稱為:ChildEvent, 
trace('Child.swf 發送 dispatchEvent(new Event( "ChildEvent" , true))')   
dispatchEvent(new Event( "ChildEvent" , true));   
}

private function _btn2ClickHandler(e:MouseEvent):void {
trace('Child.swf 發送 dispatchEvent(new CustomEvent(CustomEvent.CHILD_EVENT , true))')   
dispatchEvent(new CustomEvent( CustomEvent.CHILD_EVENT , true , "CustomEvent 並加送參數"));   
}  
public function get msg():String { return _msg; }  
}
}

CustomEvent.as
package  milkmidi{
import flash.events.Event; 
public class CustomEvent extends Event {
public static const CHILD_EVENT:String = "childEvent";  
public var msg:String;
public function CustomEvent(pType:String, pBubble:Boolean = false , pMsg:String = "") { 
super(pType, pBubble, false);
msg = pMsg;
} 

public override function toString():String { 
return formatToString("CustomEvent", "type", "msg");    
}

}

}

主檔:Main.swf Main.as
package  {
import flash.display.Loader;
import flash.display.Sprite;
import flash.events.Event;
import flash.net.URLRequest;
import milkmidi.CustomEvent;
/**
* ...
* @author milkmidi
*/
public class Main extends Sprite {  

private var _ldr:Loader;
public function Main() {
_ldr = new Loader();
_ldr.addEventListener("ChildEvent" , _childEventHandler);   
_ldr.addEventListener(CustomEvent.CHILD_EVENT , _customEventHandler);      
_ldr.load(new URLRequest("Child.swf"));
addChild(_ldr);
}

private function _customEventHandler(e:CustomEvent):void {
trace(e);
trace(e.msg);
//在偵聽CustomEvent,可以一起發送參數, 這樣就不需要在發送物件者寫一個 get 屬性。
}

private function _childEventHandler(e:Event):void {
trace(e.currentTarget , e.target);
//e.currentTarget 得到一開始注冊的物件, 也就是 _ldr
//e.target 得到真正送出事件的物件, 也就是 Child.swf
trace(e.target.msg);
//該物件有個 msg 的 get 屬性
//即可得到該變數
}

}

}
SourceCodeDownload
這樣就可以完成二個不同的.swf檔, 發送事件並加送參數, 相當的好用

留言

匿名表示…
真的好用謝謝奶老師! 有時在AS3 documentations 上看到useCapture:Boolean = false, 還有property是bubbles, value是false, 請問老師跟氣泡事件有沒有關係呢?它們是甚麼意思呢?
milkmidi寫道…
你可以看一下說明文件喔
這三個參數寫的都還滿仔細的
Edward寫道…
繼承 Event 的事件,最好也要覆寫 clone():Event 這個方法,不然當事件要再往監聽者上面傳遞的時候會有問題歐...
如果記得沒錯的話是這樣
milkmidi寫道…
clone我倒是很少去override
感謝提供的資訊,這就來去試試

這個網誌中的熱門文章

webpack2 入門實戰 1

大家好,我是奶綠茶
前端戰場不再只是寫寫 js / css , 各種框架、前處理工具百花齊放
身為前端工程師,不只要把程式寫完,還要寫好
老師說:選對好工具,事情就完成一半
如果你還在一隻 JS 打完全部程式,一隻 css 寫所有的 style
每次存檔還在手動 reload 網頁, 圖片壓 K 壓到不要不要的
透過奶綠伯的系列教學,讓你了解 webpack2 帶來的優勢
學會 webpack 可能不會加薪,但至少可以準時下班(誤)
1. 安裝 nodejs
請參考 gulp 安裝編

2. 安裝 global webpack , 筆者使用的是 2.2.1 版本
npm i webpack@2.2.1 -g
3. 在專案的根目錄放一隻 webpack.config.js
entry:你的主 js 進入點
output.filename:webpack 打包後的檔名
output.path:webpack 打包後的路徑
var path = require('path'); module.exports = { entry: './src/app.js', output: { filename: 'bundle.js', path: path.resolve(__dirname, 'dist') } };
4. require , module.exports
現在前端都 module 化
可以每個獨立的功能都寫成單一的 js module
除了好管理,也方便讓團隊使用
寫一隻 module_exports_util.js
每隻經過 webpack 打包的 js , 都會是獨立的檔案
所以變數都是私有的, 外部成員都無法得到
在這個 module 裡,我們想開放二個函式
add , getName
所以在最後的 module.exports 指定
筆記加入 jsdoc , 為了方便在開發時,能夠有型別的提示

var name = "milkmidi"; /** * @param {number} num1 * @param {number} num2 * @return {number} */ function ad…

webpack2 入門實戰 3 scss,html,file-loader

大家好,我是奶綠茶
上一篇介紹了 webpack 的核心功能 loader
這篇再來補強各種常用的 loader
css-loader:解悉 css 檔
extract-loader:這個有點難翻,下面會介紹
file-loader:存成實體的檔案, 如圖片
html-loader:解悉 html 檔
sass-loader:解悉 scss 檔
url-loader:解悉圖片路徑
webpack.config.js
module.exports = { resolveLoader: { // 所有用到的 loader, -loader 可以不用打 moduleExtensions: [ "-loader" ], }, resolve: { // 在 require 檔案, 如果不想寫完整的路徑 // 可以加入這些目錄, 讓 webpack 自動尋找對的檔案 // 請注意我們加入了 src/img 路徑,後面會再介紹到 modules: [ path.resolve( 'src/html' ), path.resolve( 'src/img' ), path.resolve( 'src/css' ), path.resolve( 'src/js' ), path.resolve( "node_modules"), ], // 在 require 時可以不用打副檔名 extensions: [ ".js", ".scss" ] }, } 再來就是 loader 的介紹
scss
在這要做多組合的應用
先將 .scss 透過 scss-loader 轉換, 並產生 sourceMap 檔
再過 css-loader
最後再過 style-loader
{ test: /\.scss$/, // 多個 loader 組合, 可寫成一行,或…

gulp 前端自動化 - spritesheet

大家好,我是奶綠茶
今天來介紹如何使用 gulp 來自動化將圖片拼成 spritesheet
奶綠我使用的套件是 gulp.spritesmith
https://www.npmjs.com/package/gulp.spritesmith
可以使用 handlebars 格式,拼出自己想要的 css 格式
{{#sprites}} .{{name}} { background-position: {{px.offset_x}} {{px.offset_y}}; width: {{px.width}}; height: {{px.height}}; background-image: url({{{escaped_image}}}); } {{/sprites}} gulp 的設定
gulp.task('sprite',()=>{ console.log('sprite'); const spriteData = gulp.src('src/sprite_src/*') .pipe(spritesmith({ imgName: '../img/sprite.png', cssName: '_sprite.css', padding: 4, imgOpts: { quality: 100 }, cssTemplate: 'src/css/handlebars/basic.handlebars', })); const imgStream = spriteData.img .pipe(buffer()) .pipe(gulp.dest('dist/img/')); const cssStream = spriteData.css .pipe(gulp.dest('src/css')); return merge(imgStream, cssStream); });…