跳到主要內容

FlashAS3 Countdown

大家好,我是奶綠茶
Countdown在 flash 的專案裡,應該也是很常出現的吧
所以我就把他包裝成一個 class , 方便使用
預設是抓取 client 端的時間
如果想要以伺服器時間為主的話
也只要使用 URLLoader 透過伺服器程式回傳時間
再更新我所寫的 Countdown類別可以。


Countdown.as
/**
 * @author milkmidi
 * @see http://milkmidi.blogspot.com
 * @version 1.0.1
 * @date created 2010/11/16/
 */
package milkmidi.utils { 
 import flash.events.Event;
 import flash.events.EventDispatcher;
 import flash.events.TimerEvent;
 import flash.utils.Timer;
 
 [Event(name = "countDownComplete" , type = "milkmidi.utils.Countdown")]
 [Event(name = "countDownUpdate"  , type = "milkmidi.utils.Countdown")]
 public class Countdown extends EventDispatcher {  
  public static const COUNTDOWN_COMPLETE :String = "countDownComplete";
  public static const COUNTDOWN_UPDATE :String = "countDownUpdate";
  private static const SEC :uint = 1000;
  private static const MIN :uint = SEC * 60;
  private static const HOUR :uint = MIN * 60;
  private static const DAY :uint = HOUR * 24;
  
  private var _endYear :uint;
  private var _endMonth :uint;
  private var _endDay  :uint;
  private var _endHour :uint;
  private var _endMin  :uint;
  private var _endDate :Date;
  //   
  private var _year :int;
  private var _month :int;
  private var _day :int;
  private var _hour :int;
  private var _min :int;
  private var _sec :int;
  private var _timer :Timer = new Timer(1000);
  private var _today :Date;
  
  /**
   * 
   * @param pYear
   * @param pMonth
   * @param pDay
   * @param pHour
   * @param pMin
   */
  public function Countdown( pYear:uint, pMonth:uint , pDay:uint , pHour:uint = 0, pMin:uint = 0  ) {   
   _endYear  = pYear ;
   _endMonth = pMonth - 1;   
   _endDay   = pDay;
   _endHour  = pHour;
   _endMin   = pMin;   
   _endDate = new Date(_endYear, _endMonth , _endDay, _endHour , _endMin);    
   _timer.addEventListener(TimerEvent.TIMER , timerHandler);
  }   
  /**
   * 
   * @param pYear
   * @param pMonth
   * @param pDay
   * @param pHour
   * @param pMin
   */
  public function setNewDate(pYear:uint, pMonth:uint , pDay:uint , pHour:uint = 0, pMin:uint = 0):void {   
   _today = new Date(pYear , pMonth - 1 , pDay , pHour , pMin);
  }
  public function start():void {   
   _timer.start();
   timerHandler(null);
  }
  public function stop():void {
   _timer.stop();     
  }
  private function timerHandler(e:TimerEvent):void {     
   var _todayDate:Date;
   if (_today == null) 
    _todayDate = new Date();
   else 
    _todayDate = new Date(_today.getTime() + _timer.currentCount * 1000);     
   
   
   
   var differ  :Number = _endDate.getTime() - _todayDate.getTime();     
   _day  = Math.floor(differ / DAY);
   differ -= _day * DAY;
   _hour  = Math.floor(differ / HOUR);
   differ -= _hour * HOUR;
   _min  = Math.floor(differ / MIN);
   differ -= _min * MIN;
   _sec = Math.floor(differ / SEC);
   
   
   if (_day < 0) {
    stop();
    _year = _month = _day = _hour = _min = _sec = 0;
    dispatchEvent(new Event(COUNTDOWN_COMPLETE));            
   }else {
    dispatchEvent(new Event(COUNTDOWN_UPDATE));
   }   
  }
  public function destroy():void {     
   stop();
   _timer = null;
  }
  public function get year() :uint { return _year; }  
  public function get sec() :uint { return _sec;  }  
  public function get min() :uint { return _min;  }  
  public function get hour() :uint { return _hour;  }  
  public function get day() :uint { return _day;  }  
  public function get month() :uint { return _month;  }
  override public function toString():String {
   return "year:" + year + " month:" + month + " day:" + day + " hour:" + hour + " min:" + min + " sec:" + sec;
  }
 }
}
測試:
/**
 * @mxmlc -o deploy/CountdownDemo.swf -default-size 800 600 -optimize=true -default-frame-rate=36 -default-background-color=0xffffff -debug=false
 * @author milkmidi
 * @see http://milkmidi.blogspot.com
 * @version 1.0.1
 * @date created 2010/11/16/
 */
package  {  
 import flash.display.Sprite;
 import flash.events.Event;
 import flash.text.TextField;
 import milkmidi.utils.Countdown;
 public class CountdownDemo extends Sprite {  
  
  private var _tf:TextField;
  private var _cd:Countdown;
  public function CountdownDemo()  {   
   
   addChild(_tf = new TextField);
   _tf.width = 300;
   
   
   //預設是使用 client 端的時間
   _cd = new Countdown(2010, 12, 31);
   _cd.addEventListener(Countdown.COUNTDOWN_UPDATE , _countDownUpDateHandler);
   _cd.addEventListener(Countdown.COUNTDOWN_COMPLETE , _countDownCompleteHandler);
   _cd.start();
   
   // 從伺服器抓到正確的時間後, 把時間填寫入函式,即可更新
   //_cd.setNewDate(年,月,日,時,分)
  }  
  
  private function _countDownCompleteHandler(e:Event):void {
   _tf.text = "Happy new year";
  }
  
  private function _countDownUpDateHandler(e:Event):void {
   _tf.text = _cd.toString();
  }   
  
 }
}
轉載請註明出處 http://milkmidi.blogspot.com/2010/11/flashas3-countdown.html

留言

柚子寫道…
請問奶綠大~
[Event(name = "countDownComplete" , type = "milkmidi.utils.Countdown")]

這種寫法GOOGLE關鍵字該查什麼呢?
不明白這種寫法。

謝謝奶綠大~
milkmidi寫道…
柚子你好
那段語法的意思是宣告該類別會發出該事件
但加不加都無所謂

如果有加的話
var c:Countdown = new Countdown ();
c.addEventListener( 打到這時,就會出現上方有宣告的 Event 類型
沒加的話,就不會提示。

你可以看到 Flex 的 Source 裡,都有加入這個 Tag
柚子寫道…
^___^謝謝奶綠大~

這個網誌中的熱門文章

超好用的無限免費網頁空間,無廣告,無流量限制

大家好,我是奶綠茶
今天來教大家如何申請一個無限免費速度又快的網頁空間
1 首先到 https://github.com/ 申請帳號(一直下一步,下一步,下一步)
2 到你的個人頁,切換上方的 tab 到 Repositories, 按下右鍵的 new

3 Repository name
一定要是這樣的格式 username.github.io
我的 github 網址是 github.com/milkmidi
那就要輸入 milkmidi.github.io
選擇 public, 這樣別人才看的到
private 有其他用途, 而且要付費才能使用
完成後按下 Create repository


5 安裝 SourceTree
github 並不支援 FTP 或是網頁上傳,一定要透過指令碼
在這我們選用有圖型介面的軟體,方便大家學習
https://www.sourcetreeapp.com/
下載並安裝
啟動後登入你的 github 帳號

6 clone 你的 github io 專案
右上角有個 Clone or download 點選後
複製 https 連結(不要選到 ssh )


7 將 https 的連結貼到 SourceTree



8 上傳 html
到本機 github.io 資料夾,放一個 index.html
切換到 SourceTree, 這時會看到 Unstaged files 的欄位
選擇 Stage All


9 git 要求每次的 Commit, 都一定要打說明文字(好習慣)
輸入完成後,按下右邊的 Commit


10 發佈(Push),這樣就完成啦
可以到你的 http://milkmidi.github.io/ 去查看檔案有沒有出來


其他
Commit 可以想像是做一個記錄,你可以很多的 Commit
最後再一次 Push 上去
github 原本是給程式設計師用的版本控管服務
免費版提供無限空間讓你放檔案,但一定要是 public
想要有私有的 Project ,就只能付費
github.io 只能放靜態檔案,php, aspx 服務並不支援。
祝大家學習愉快

轉載請註明出處

奶綠的 github.io Source Code

Android完全入門篇-01 安裝SDK與裝置USBDriver

大家好,我是奶綠茶
筆者以 Windows 系統來介紹安裝
1. 下載 Android SDK
http://developer.android.com/sdk/index.html
有分 32 位元和 64 位元的版本
為了教學方便,筆者將檔案放置在 D:\ 下
壓開後會有
eclipse資料夾:Eclipse程式碼編譯器
sdk:Android 開發用的 SDK
SDK Manager.exe:sdk管理用的軟體


2. 開啟手機的"開發人員選項"
部份手機該選項被隱藏起來了
要開啟的話,點選"關於手機"
接著連點"版本號碼"七次,就會重新開啟該功能
接著再開啟"USB偵錯"功能
接上你的 USB 線後
這樣你的電腦才能透過 USB 線來偵錯手機的資訊
3. 為裝置安裝 adb usb driver
因為各家廠牌的 Driver 都不同也不通用,所以需要自行 Google 找 Driver
可以用"XXX廠牌 型號 adb usb driver"關鍵字來找
例:HTC Newone adb usb driver
接著找到 我的電腦 / 內容


裝置管理員

會看到一個金嘆號未知的裝置, 按右鍵更新驅動程式軟體

選擇"瀏覽電腦上的驅動程式軟體"

完成後就會看到裝置啟動,並出現 XXX Android ADB Interface

4.測試是否連接成功
進入到第一步下載的 sdk 資料夾裡
D:\adt-bundle-windows-x86_64-20131030\sdk
然後在 platform-tools 資料夾上按住 Shift 鍵,然後再按滑鼠右鍵
選擇"在此處開啟命令視窗"
(此功能只有 Win7 之後的版本才支援, XP使用者就要自行輸入 dos 指令進入到資料夾)
輸入 adb devices
如果看到一串數字,並顯示 device 就表示連線成功
5.新增環境變數(選擇性設定)
為了方便的使用 adb 指令
可以為 windows 設定變數
開啟我的電腦 / 內容 / 左邊的"進階系統設定"
點選下方 環境變數

下方系統變數,找到 Path的選項,按下編輯

在變數值欄位的最後方加入
;D:\adt-b…

前端攻城屍自動化教學 1 (入門軟體篇, 使用 prepros)

大家好,我是奶綠茶
寫程式的最高原則,就是要"懶"
"懶"指的是 "雜事交由電腦幫你完成"
你就可以專心在程式面上
比如說:
uglifyjs JS 自動幫你把 JS 壓成一行
自動幫你轉 sass/ scss
程式碼一存檔,html 就自動 reload
如果這些事還要手動處理就真的麻煩了

新手可以直接使用現成的軟體
https://prepros.io/
這是一套永久免費的軟體(如果覺的好用也支持一下作者)
免費版和正式版的功能都一樣,差在免費版三不五時會貼心的提醒你要不要付費

1. 下載軟體, 支援 PC(不支援 XP ) 和 Mac
2. 安裝, 一直下一步下一步下一步
3. 啟動軟體



4. 把你的專案資料夾拉進 prepros

5. 點選你的 js 檔
可以看到有五個選項
Auto Compile:當你存檔時是否要自動編譯,當然是要打勾呀。
SourceMaps:產生 sourcemap 檔,通常會搭配下方的 UglifyJS。
Uglify JS:幫你把 js 壓縮成一行。
Convert ES6 to ES5:將 ES6 的語法自動轉成 ES6。
Mangle Variables:將非全域變數的名字打亂。
筆者通常都是全勾。



6. 點選你的 css 檔
AutoCompile:是否存檔自動編譯
AutoPrefixCSS:自動加入 css3的 -web-kit 等前綴字。
SourceMaps:產生 sourceMap檔。
CompressCSS:將 css 壓縮成一行
Enable Cssnext:這個我還沒認真研究


7. 點選你的 html,接下右鍵
可以看到一個 Live Preview This File
按下後會啟動一個 localhost 的網頁,之後只要有修改 js, css ,都會自動 reload

8. 加掛 Proxy
live reload 預設只能跑 html, 如果想要執行 php 或是 asp.net 的話
可以在設定裡面開啟 Live Preview Custom Server

9. 其他
Prepros 也整合了 FTP ,可以讓你方便的直接上傳檔案

轉載請註明出處
SourceCodeDownload