跳到主要內容

PV3D_方塊加速與減速

這次使用PV3D Cube來製作簡單的加速與減速效果。
還是要來聊一下簡單的物理
一個靜止的物件, 不斷加上一個等加速度
這個物件就會以直線的方式運動。
EX:
var vx:int = 2
enterFrame運算 {
球.x += vx;
}
這樣球物件隨著時間的增加, 就一直往x軸的方向每次移動2個值
如果要快一點, 就把vx速率調高
那如果要減速呢?
只要在速率乘上一個衰竭值
EX:
var vx:int = 100
vx *= 0.98
enterFrame運算 {
球.x += vx;
}
隨著時間的增加, 速率就會越來越小, 直到靜止
好,那我們把這樣的公式丟到PV3D裡的Cube裡

Thumbnail - Click me

完整程式碼

/* 
Copyright (c) 2009 milkmidi 
All rights reserved.
http://milkmidi.com
http://milkmidi.blogspot.com
*/
package
{  
import flash.display.Sprite;
import flash.events.Event;  
import flash.events.MouseEvent;
import flash.geom.Point;
import org.papervision3d.cameras.CameraType;
import org.papervision3d.lights.PointLight3D;
import org.papervision3d.materials.shadematerials.PhongMaterial;
import org.papervision3d.objects.DisplayObject3D;
import org.papervision3d.view.BasicView;
import org.papervision3d.materials.utils.MaterialsList;
import org.papervision3d.objects.primitives.Cube;
import org.papervision3d.events.InteractiveScene3DEvent;
[SWF(width = "950", height = "500", frameRate = "41", backgroundColor = "#111111", pageTitle = "milkmidi.com")]
public class PV3DCubeRotationDemo extends BasicView
{ 
private var rootNode :DisplayObject3D;
private var cube  :Cube;  

private var vx   :Number = 0;
private var vy   :Number = 0;
//速率
private var decay  :Number = .98;
//衰竭值  
private var mousePos :Point = new Point();
private var isMouseDown :Boolean = false;

public function PV3DCubeRotationDemo(){
super(0, 0, true, true, CameraType.TARGET);               
camera.z = -950;   
camera.focus = 12;    
init3DObjects();         
this.addEventListener(Event.ADDED_TO_STAGE , addToStageHandler);
} 

private function addToStageHandler(e:Event):void {
startRendering();   
stage.addEventListener(MouseEvent.MOUSE_DOWN, function (e:MouseEvent):void {
isMouseDown = true;
mousePos.x = stage.mouseX;
mousePos.y = stage.mouseY;
});
stage.addEventListener(MouseEvent.MOUSE_UP, function (e:MouseEvent):void {
isMouseDown = false;
});

/*這段程式不用理他
var _copy:CopyrightMC = new CopyrightMC();
_copy.text = "PV3DCubeRotationDemo";
_copy.color = 0xffffff;
this.addChild(_copy);
*/
}
private function init3DObjects():void {
rootNode = new DisplayObject3D();      
scene.addChild(rootNode);

var _light  :PointLight3D = new PointLight3D();
var _phongMat:PhongMaterial = new PhongMaterial(_light, 0xffffff, 0x999999, 10);        
var _ml   :MaterialsList = new MaterialsList( { all:_phongMat } );      
cube = new Cube(_ml, 400, 400, 400);   
rootNode.addChild(cube);      
}  
override protected function onRenderTick(e:Event = null):void {
if (isMouseDown == true) {       
var _differenceX:int = mousePos.x - stage.mouseX;
var _differenceY:int = mousePos.y - stage.mouseY; 
//算出上一個滑鼠座標和現在座標的距離差

cube.rotationY += _differenceX;
rootNode.rotationX += _differenceY;



mousePos.x = stage.mouseX;
mousePos.y = stage.mouseY; 

vx = _differenceX / 10;   
vy = _differenceY / 10;

}else {   
/*
* 用上一個滑鼠座標的位置, 減去現在座標的位置
* 即可用來當作加速度, 
* 加速度再乘上一個衰竭值,
* 即可讓加速度慢慢的漸近於0, 
* 物件也就可以慢慢的靜止, 
* 直到又賦予一個新的加速度。
* */    
vx *= decay;
vy *= decay;
cube.rotationY += vx;
rootNode.rotationX += vy;
}    
super.onRenderTick(e);
}  
}
}



留言

chiou寫道…
奶老師,感謝您的分享!
好Yeh人寫道…
奶綠老師您好
在PV3D中我設計了透過滑鼠滾輪讓攝影機zoom的功能,但在操作時一開始,使用者都必須先在畫面用滑鼠點擊一次,才能夠開始滑鼠的滾輪作用,請問這是怎麼樣的問題呢?可以給我點建議嗎?

謝謝你^^
milkmidi寫道…
我之前也遇到,
但現在怎麼測都可以偵測的到MouseWheel事件, 我再來再一下原因再來分享心得
好Yeh人寫道…
謝謝奶綠老師
(BTW...老師吉他彈不錯內)
milkmidi寫道…
哈, 謝謝喔
我熱愛吉他, 更熱愛Flash
阿信表示…
奶綠老師您好
一開始旋轉方向正確
旋轉一個方向到180度
之後遇到旋轉方向卻是相反
是因為沒有Z軸關係嗎
還是要怎麼修正

謝謝您
milkmidi寫道…
因為轉超過一定的度數了,我再來想想怎麼改

這個網誌中的熱門文章

webpack2 入門實戰 1

大家好,我是奶綠茶
前端戰場不再只是寫寫 js / css , 各種框架、前處理工具百花齊放
身為前端工程師,不只要把程式寫完,還要寫好
老師說:選對好工具,事情就完成一半
如果你還在一隻 JS 打完全部程式,一隻 css 寫所有的 style
每次存檔還在手動 reload 網頁, 圖片壓 K 壓到不要不要的
透過奶綠伯的系列教學,讓你了解 webpack2 帶來的優勢
學會 webpack 可能不會加薪,但至少可以準時下班(誤)
1. 安裝 nodejs
請參考 gulp 安裝編

2. 安裝 global webpack , 筆者使用的是 2.2.1 版本
npm i webpack@2.2.1 -g
3. 在專案的根目錄放一隻 webpack.config.js
entry:你的主 js 進入點
output.filename:webpack 打包後的檔名
output.path:webpack 打包後的路徑
var path = require('path'); module.exports = { entry: './src/app.js', output: { filename: 'bundle.js', path: path.resolve(__dirname, 'dist') } };
4. require , module.exports
現在前端都 module 化
可以每個獨立的功能都寫成單一的 js module
除了好管理,也方便讓團隊使用
寫一隻 module_exports_util.js
每隻經過 webpack 打包的 js , 都會是獨立的檔案
所以變數都是私有的, 外部成員都無法得到
在這個 module 裡,我們想開放二個函式
add , getName
所以在最後的 module.exports 指定
筆記加入 jsdoc , 為了方便在開發時,能夠有型別的提示

var name = "milkmidi"; /** * @param {number} num1 * @param {number} num2 * @return {number} */ function ad…

超好用的無限免費網頁空間,無廣告,無流量限制

大家好,我是奶綠茶
今天來教大家如何申請一個無限免費速度又快的網頁空間
1 首先到 https://github.com/ 申請帳號(一直下一步,下一步,下一步)
2 到你的個人頁,切換上方的 tab 到 Repositories, 按下右鍵的 new

3 Repository name
一定要是這樣的格式 username.github.io
我的 github 網址是 github.com/milkmidi
那就要輸入 milkmidi.github.io
選擇 public, 這樣別人才看的到
private 有其他用途, 而且要付費才能使用
完成後按下 Create repository


5 安裝 SourceTree
github 並不支援 FTP 或是網頁上傳,一定要透過指令碼
在這我們選用有圖型介面的軟體,方便大家學習
https://www.sourcetreeapp.com/
下載並安裝
啟動後登入你的 github 帳號

6 clone 你的 github io 專案
右上角有個 Clone or download 點選後
複製 https 連結(不要選到 ssh )


7 將 https 的連結貼到 SourceTree



8 上傳 html
到本機 github.io 資料夾,放一個 index.html
切換到 SourceTree, 這時會看到 Unstaged files 的欄位
選擇 Stage All


9 git 要求每次的 Commit, 都一定要打說明文字(好習慣)
輸入完成後,按下右邊的 Commit


10 發佈(Push),這樣就完成啦
可以到你的 http://milkmidi.github.io/ 去查看檔案有沒有出來


其他
Commit 可以想像是做一個記錄,你可以很多的 Commit
最後再一次 Push 上去
github 原本是給程式設計師用的版本控管服務
免費版提供無限空間讓你放檔案,但一定要是 public
想要有私有的 Project ,就只能付費
github.io 只能放靜態檔案,php, aspx 服務並不支援。
祝大家學習愉快

轉載請註明出處

奶綠的 github.io Source Code

webpack2 入門實戰 3 scss,html,file-loader

大家好,我是奶綠茶
上一篇介紹了 webpack 的核心功能 loader
這篇再來補強各種常用的 loader
css-loader:解悉 css 檔
extract-loader:這個有點難翻,下面會介紹
file-loader:存成實體的檔案, 如圖片
html-loader:解悉 html 檔
sass-loader:解悉 scss 檔
url-loader:解悉圖片路徑
webpack.config.js
module.exports = { resolveLoader: { // 所有用到的 loader, -loader 可以不用打 moduleExtensions: [ "-loader" ], }, resolve: { // 在 require 檔案, 如果不想寫完整的路徑 // 可以加入這些目錄, 讓 webpack 自動尋找對的檔案 // 請注意我們加入了 src/img 路徑,後面會再介紹到 modules: [ path.resolve( 'src/html' ), path.resolve( 'src/img' ), path.resolve( 'src/css' ), path.resolve( 'src/js' ), path.resolve( "node_modules"), ], // 在 require 時可以不用打副檔名 extensions: [ ".js", ".scss" ] }, } 再來就是 loader 的介紹
scss
在這要做多組合的應用
先將 .scss 透過 scss-loader 轉換, 並產生 sourceMap 檔
再過 css-loader
最後再過 style-loader
{ test: /\.scss$/, // 多個 loader 組合, 可寫成一行,或…