跳到主要內容

PV3D_方塊加速與減速

這次使用PV3D Cube來製作簡單的加速與減速效果。
還是要來聊一下簡單的物理
一個靜止的物件, 不斷加上一個等加速度
這個物件就會以直線的方式運動。
EX:
var vx:int = 2
enterFrame運算 {
球.x += vx;
}
這樣球物件隨著時間的增加, 就一直往x軸的方向每次移動2個值
如果要快一點, 就把vx速率調高
那如果要減速呢?
只要在速率乘上一個衰竭值
EX:
var vx:int = 100
vx *= 0.98
enterFrame運算 {
球.x += vx;
}
隨著時間的增加, 速率就會越來越小, 直到靜止
好,那我們把這樣的公式丟到PV3D裡的Cube裡

Thumbnail - Click me

完整程式碼

/* 
Copyright (c) 2009 milkmidi 
All rights reserved.
http://milkmidi.com
http://milkmidi.blogspot.com
*/
package
{  
import flash.display.Sprite;
import flash.events.Event;  
import flash.events.MouseEvent;
import flash.geom.Point;
import org.papervision3d.cameras.CameraType;
import org.papervision3d.lights.PointLight3D;
import org.papervision3d.materials.shadematerials.PhongMaterial;
import org.papervision3d.objects.DisplayObject3D;
import org.papervision3d.view.BasicView;
import org.papervision3d.materials.utils.MaterialsList;
import org.papervision3d.objects.primitives.Cube;
import org.papervision3d.events.InteractiveScene3DEvent;
[SWF(width = "950", height = "500", frameRate = "41", backgroundColor = "#111111", pageTitle = "milkmidi.com")]
public class PV3DCubeRotationDemo extends BasicView
{ 
private var rootNode :DisplayObject3D;
private var cube  :Cube;  

private var vx   :Number = 0;
private var vy   :Number = 0;
//速率
private var decay  :Number = .98;
//衰竭值  
private var mousePos :Point = new Point();
private var isMouseDown :Boolean = false;

public function PV3DCubeRotationDemo(){
super(0, 0, true, true, CameraType.TARGET);               
camera.z = -950;   
camera.focus = 12;    
init3DObjects();         
this.addEventListener(Event.ADDED_TO_STAGE , addToStageHandler);
} 

private function addToStageHandler(e:Event):void {
startRendering();   
stage.addEventListener(MouseEvent.MOUSE_DOWN, function (e:MouseEvent):void {
isMouseDown = true;
mousePos.x = stage.mouseX;
mousePos.y = stage.mouseY;
});
stage.addEventListener(MouseEvent.MOUSE_UP, function (e:MouseEvent):void {
isMouseDown = false;
});

/*這段程式不用理他
var _copy:CopyrightMC = new CopyrightMC();
_copy.text = "PV3DCubeRotationDemo";
_copy.color = 0xffffff;
this.addChild(_copy);
*/
}
private function init3DObjects():void {
rootNode = new DisplayObject3D();      
scene.addChild(rootNode);

var _light  :PointLight3D = new PointLight3D();
var _phongMat:PhongMaterial = new PhongMaterial(_light, 0xffffff, 0x999999, 10);        
var _ml   :MaterialsList = new MaterialsList( { all:_phongMat } );      
cube = new Cube(_ml, 400, 400, 400);   
rootNode.addChild(cube);      
}  
override protected function onRenderTick(e:Event = null):void {
if (isMouseDown == true) {       
var _differenceX:int = mousePos.x - stage.mouseX;
var _differenceY:int = mousePos.y - stage.mouseY; 
//算出上一個滑鼠座標和現在座標的距離差

cube.rotationY += _differenceX;
rootNode.rotationX += _differenceY;



mousePos.x = stage.mouseX;
mousePos.y = stage.mouseY; 

vx = _differenceX / 10;   
vy = _differenceY / 10;

}else {   
/*
* 用上一個滑鼠座標的位置, 減去現在座標的位置
* 即可用來當作加速度, 
* 加速度再乘上一個衰竭值,
* 即可讓加速度慢慢的漸近於0, 
* 物件也就可以慢慢的靜止, 
* 直到又賦予一個新的加速度。
* */    
vx *= decay;
vy *= decay;
cube.rotationY += vx;
rootNode.rotationX += vy;
}    
super.onRenderTick(e);
}  
}
}



留言

ChiouChu寫道…
奶老師,感謝您的分享!
好Yeh人寫道…
奶綠老師您好
在PV3D中我設計了透過滑鼠滾輪讓攝影機zoom的功能,但在操作時一開始,使用者都必須先在畫面用滑鼠點擊一次,才能夠開始滑鼠的滾輪作用,請問這是怎麼樣的問題呢?可以給我點建議嗎?

謝謝你^^
milkmidi寫道…
我之前也遇到,
但現在怎麼測都可以偵測的到MouseWheel事件, 我再來再一下原因再來分享心得
好Yeh人寫道…
謝謝奶綠老師
(BTW...老師吉他彈不錯內)
milkmidi寫道…
哈, 謝謝喔
我熱愛吉他, 更熱愛Flash
阿信表示…
奶綠老師您好
一開始旋轉方向正確
旋轉一個方向到180度
之後遇到旋轉方向卻是相反
是因為沒有Z軸關係嗎
還是要怎麼修正

謝謝您
milkmidi寫道…
因為轉超過一定的度數了,我再來想想怎麼改

這個網誌中的熱門文章

奶綠茶新書上市_密技公怖_程式碼下載

奶綠茶第一本 Flash 書籍上市啦 博客來書籍館 Flash 3D 特效宅急便 - 商業範例隨學隨 把我對 Flash 的研究與熱愛, 全寫在其中 本書的前幾章, 特別安排 ActionScript3.0 的許多範例 好讓你一步步瞭解 as2 和 as3 的差別 再安排製作動畫不可缺少的 Tweener 類別和一些常用的數學動畫公式 最後當然就來到本書的重點 PV3D 啦 從 PV3D 的原理, 基本架構一點一點的介紹 再透過許多實用的範例, 從中瞭解 PV3D 製作的小技巧 有任何書籍相關的問題, 也請不吝指教 感謝一路走來, 幫助過我的前輩們, 邦邦、Ticore、神魂、Maso、Erin 旗標出版社 小編 Bready 米蘭數位所有夥伴 米蘭數位ActionScript Team:Jason,Ash,Mark 本書大鋼: 1.ActionScript3.0概論 分析AS3的概念與語法, 從基本的滑鼠事件、外部載入、氣泡事件介紹起 適合熟悉AS2, 想轉戰AS3的人員。 2.程式碼製作動畫 使用簡單的數學公式, 套用到程式裡, 脫離死版的影格動畫。 3.製作動畫的好夥伴:Tweener 除了套用數學公式外, Tweener類別也能加速我們開發出更多的動畫效果, 不需辛辛苦苦的找公式。 4.自定類別 AS3的精神, 是在於強大的物件導向, 當然也要熟悉類別的寫法與使用。 5.Flash3D - Papervison3D 如果在Flash玩轉3D效果, PV3D是最好學, 最快上手的3D Flash Engine, 從簡單的3D概念, PV3D類別, 事件等。 6 漫天飛舞的Paper3DWorld效果 7 迷你旋轉木馬式秀圖效果 8 最經典! CoverFlow 圖像展示效果 9 天旋地轉 TiltViewer效果 10 FlatWall3D電視牆效果 11 經典旋轉木馬 Carousel3D 秀圖效果 12 光源材質展示與簡易型的方塊彈跳效果 13 載入外部3D模型與動畫 14 超立體旋轉九宮格 Box3DWorld 15 空間感與透明感兼具的 SpaceGallery 16 螺旋式 SpiralCarouse 影像展示 17 Flash10 3D功能 18 Flash效

奶綠茶photoGalleryV3.5

奶小茶的photoGalleryV3.5原始檔 2007/12/30 更新小Bug,請重新下載 線上Demo: http://milkmidi.com/photogallery/galleryv3.html 1.支援SWFAddress,讓FLASH可以有上一頁下一頁和每張獨立網址的功能 2.圖片路徑圖說經由XML來設定 3.背景依據顯示圖片,自動變化成最接近的顏色 4.非商業用途,歡迎使用並修改(如果覺得我製作的好,也煩請加入我的logo) 5.可結合後端伺服器 00.art 相本集資料夾 com 奶綠茶的Class檔 swfaddress SWFAddress資料夾 swfobject swfobject資料夾 XML galleryV3.fla 原始檔 index.html 主檔html SWFAddress.as SWFaddressEvent.as Source Code Download 解壓密碼:回覆文章,即可看見Password

超好用的無限免費網頁空間,無廣告,無流量限制

大家好,我是奶綠茶 今天來教大家如何申請一個無限免費速度又快的網頁空間 1 首先到  https://github.com/ 申請帳號(一直下一步,下一步,下一步) 2 到你的個人頁,切換上方的 tab 到 Repositories, 按下右鍵的 new 3 Repository name 一定要是這樣的格式 username.github.io 我的 github 網址是 github.com/milkmidi 那就要輸入 milkmidi.github.io 選擇 public, 這樣別人才看的到 private 有其他用途, 而且要付費才能使用 完成後按下 Create repository 5 安裝 SourceTree github 並不支援 FTP 或是網頁上傳,一定要透過指令碼 在這我們選用有圖型介面的軟體,方便大家學習 https://www.sourcetreeapp.com/ 下載並安裝 啟動後登入你的 github 帳號 6 clone 你的 github io 專案 右上角有個 Clone or download 點選後 複製 https 連結(不要選到 ssh ) 7 將 https 的連結貼到 SourceTree 8 上傳 html 到本機 github.io 資料夾,放一個 index.html 切換到 SourceTree, 這時會看到 Unstaged files 的欄位 選擇 Stage All 9 git 要求每次的 Commit, 都一定要打說明文字(好習慣) 輸入完成後,按下右邊的 Commit 10 發佈(Push),這樣就完成啦 可以到你的 http://milkmidi.github.io/ 去查看檔案有沒有出來 其他 Commit 可以想像是做一個記錄,你可以很多的 Commit 最後再一次 Push 上去 github 原本是給程式設計師用的版本控管服務 免費版提供無限空間讓你放檔案,但一定要是 public 想要有私有的 Project ,就只能付費 github.io 只能放靜態檔案,php, aspx 服務並不支援。 祝大家學習愉快 轉載請註明出處 奶綠的 github.io S